Voici un petit détail de chaque méthode, qui vont vous faciliter la vie en AS3 :

Array.forEach() : Execute une fonction sur chaque élément 
var monArray:Array = [12, 58, "bob"];
			
monArray.forEach (navigate);

private function navigate(element:*, index:int, arr:Array):void {
			
	trace( element + " :: " + index + " :: " + arr );
			
}
Sortie : 
12 :: 0 :: 12,58,bob
58 :: 1 :: 12,58,bob
bob :: 2 :: 12,58,bob

Array.every() : Execute une fonction sur chaque élément tant que la fonction renvoie true pour l'élément parcouru 
var monArray:Array = [12, 58, "bob"];
			
var isAStringArray:Boolean = monArray.every (navigate);
			
trace ( isAStringArray );

private function navigate(element:*, index:int, arr:Array):Boolean {
			
	return  ( element is String );
			
}
Sortie : 
false
Array.map() : Construit un nouveau tableau à partir du retour de la fonction 
var monArray:Array = ["steven groove", "ritchie funk", "billy jazzy"];
			
var newArray:Array = monArray.map (navigate);
			
trace ( newArray );

private function navigate(element:*, index:int, arr:Array):String {

	return String (element).charAt(0).toUpperCase() + String (element).substr(1).toLowerCase();
			
}
Sortie : 
Steven groove,Ritchie funk,Billy jazzy
Array.filter() :Construit un nouveau tableau incluant chaque élement validé par la condition 
var monArray:Array = [{name : "bob", age : 17}, 
				       {name : "ritchie", age : 25}, 
				       {name : "bobby", age : 14} ];
			
var over18:Array = monArray.filter (navigate);
			
over18.forEach ( showelements );
			
		
private function navigate(element:*, index:int, arr:Array):Boolean {

	return element.age >= 18;
			
}
		
private function showelements(element:*, index:int, arr:Array):void {

	trace( element.name + " :: " + element.age );
			
}
Sortie : 
ritchie :: 25
Array.some() : Execute une fonction sur chaque élément jusqu'à ce que la fonction renvoie true 
var monArray:Array = [{name : "bob", sex : "M"}, 
                               {name : "ana", sex : "F"}, 
                               {name : "bobby", sex : "M"} ];
			
var anyWomen:Boolean = monArray.some (navigate);
			
trace( anyWomen );

private function navigate(element:*, index:int, arr:Array):Boolean {

	return element.sex == "F";
			
}
Sortie : 
true
Array.indexOf() : Retourne la position de l'élement recherché dans le tableau 
var monArray:Array = ["bob", "ana", "bobby", "ana" ];
			
var result:int = monArray.indexOf ("ana");
			
var result2:int = monArray.lastIndexOf ("ana");
			
trace( result + " :: " + result2 );
Sortie : 
1 :: 3